En nuestra propuesta de métrica para obras creativas (Wiki3DRank, basada en datos de Wikipedia-Wikidata), encontramos un problema para algunas obras que también circulan y se conocen en partes. Hay diferentes casos con diferentes condiciones:
- La Biblia. La biblia es en sí un libro compuesto, un canon que selecciona y agrupa diferentes relatos. Dada su gran difusión e impacto cultural, sus principales relatos también son bien conocidos como títulos individuales, aunque no sea frecuente su edición separada: El Génesis; El evangelio de San Marcos, El nuevo testamento, La epístola a los Corintios, ...
- El señor de los anillos. Este caso ha tenido vida editorial como libro completo, pero también, dada su gran extensión, se ha publicado en tres volúmenes y algunos anexos menores.
- Sherlock Holmes. Cuando hablamos de los libros de Sherlock Holmes en realidad nos referimos a un serie de libros, libros de relatos y relatos, que forman el canon holmesiano.
En Wikidata podemos conseguir la información de las piezas que componen estos puzzles de diferentes formas. Veamos las consultas SPARQL que nos permitirían explorar estas obras agregadas:
EL SEÑOR DE LOS ANILLOS
La consulta SPARQL haría uso de la propiedad P527 (has parts). Con esta query obtenemos las partes de esta trilogía: Los tres libros (Comunidad, Torres, Retorno) y dos pequeñas piezas marginales (Prólogo, Anexos).
SELECT ?parte ?parteLabel WHERE {
wd:Q15228 wdt:P527 ?parte
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". } }
parte | parteLabel |
---|---|
wd:Q208002 | The Fellowship of the Ring |
wd:Q332139 | Prologue |
wd:Q332388 | The Two Towers |
wd:Q332581 | The Return of the King |
wd:Q334335 | Appendices of the Lord of the Rings |
LA BIBLIA
Esta misma estrategia de selección aplicada sobre La Biblia, produce unos resultados insatisfactorios, porque solamente se ofrecen las dos agrupaciones superiores - Nuevo y viejo testamento - y además propone otra parte que se solapa con una de las otras, La biblia hebrea.
parte | parteLabel |
---|---|
wd:Q18813 | New Testament |
wd:Q19786 | Old Testament |
wd:Q732870 | Hebrew Bible |
Si hacemos la búsqueda recursiva, encontramos 1312 resultados, lo cual en principio parece que se nos sale de madre. La Biblia es una colección extensa, pero no debería ser tanto.
SELECT ?parte ?parteLabel WHERE {
wd:Q1845 wdt:P527* ?parte
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". } }
Podemos tener un esquema más preciso si usamos uno de los Graph Services del WDQS, el para consultar grafos, y ordenar/agrupar las partes obtenidas según el nivel y delimitar hasta dónde parece útil recorrer el grafo. Cogiendo los niveles 1 y 2 tenemos una suficiente representación de los 79 "libros" que componen La Biblia, un número que, sin entrar en detalles eruditos, encaja con el conocimiento convencional sobre esta obra.
SELECT ?superior ?superiorLabel ?elemento ?elementoLabel ?depth WHERE
{
SERVICE gas:service {
gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.BFS" ; gas:in wd:Q1845 ; gas:linkType wdt:P527 ; gas:out ?elemento ; gas:out1 ?depth ; gas:out2 ?superior . }
FILTER(?depth < 3)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} order by ?depth
superior | superiorLabel | elemento | elementoLabel | depth |
---|---|---|---|---|
wd:Q1845 | Bible | wd:Q19786 | Old Testament | 1 |
wd:Q1845 | Bible | wd:Q18813 | New Testament | 1 |
wd:Q1845 | Bible | wd:Q732870 | Hebrew Bible | 1 |
wd:Q19786 | Old Testament | wd:Q131072 | Ecclesiastes | 2 |
wd:Q18813 | New Testament | wd:Q131095 | Epistle to the Colossians | 2 |
wd:Q18813 | New Testament | wd:Q131097 | Epistle of James | 2 |
wd:Q18813 | New Testament | wd:Q131101 | First Epistle of John | 2 |
wd:Q18813 | New Testament | wd:Q131104 | Epistle to Philemon | 2 |
LOS LIBROS DE SHERLOCK HOLMES
El canon holmesiano es el conjunto de escritos (novelas y colecciones de relatos) de autoría exclusiva de Arthur Conan Doyle que componen la bibliografía del famoso detective Sherlock Holmes. Se usa el término «canon» para distinguirlos de los demás relatos escritos con posterioridad por otros autores y basados en los personajes creados por Conan Doyle.
Existe un elemento para este canon en Wikidata, Q2316684 (Tipificado como "Serie de libros", Q277759), el cual nos podría servir de punto de partida. En el caso de los relatos nos encontramos con la diferencia entre la obra y la edición. El relato es la obra, pero no suele publicarse independientemente: aparece dentro de una publicación seriada o en una colección de relatos. En el canon Holmesiano tendríamos 9 libros (algunos novela y otros, colecciones de relatos). En realidad, contando solo los libros-historia y los relatovs, tendríamos unos 60 piezas, sin afinar en las cuentas.
En este caso, tanto al consulta recursiva como la consulta con el Graph Service ofrecen resultados insuficientes: 21 elementos. Sin embargo, cada una de las obras del canon de Holmes tiene su propio artículo en Wikipedia y, por tanto, su propio item en Wikidata.
Cada relato está vinculado a una serie a través de la propiedad P179 y también a una publicación, mediante P1433 (Que puede ser un libro o una revista).
![1021: Little Fictions – 'A Scandal in Bohemia' (1891) by Sir Arthur Conan Doyle | The Invisible Event](https://theinvisibleevent.files.wordpress.com/2023/01/adventures-of-sherlock-holmes.jpg)
El relato "Escándalo en Bohemia" está descrito así:
- P179 (Serie) Las aventuras de Sherlock Holmes; Canon Holmesiano
- P1433 (Publicado en) The Strand Magazine
![Una nueva y completa historia de Sherlock Holmes. La aventura del vampiro de Sussex. También Conan Doyle sobre Sherlock Holmes en sus reminiscencias. Una imagen de Sherlock Holmes. The Strand Magazine :](https://l450v.alamy.com/450ves/r5g2km/una-nueva-y-completa-historia-de-sherlock-holmes-la-aventura-del-vampiro-de-sussex-tambien-conan-doyle-sobre-sherlock-holmes-en-sus-reminiscencias-una-imagen-de-sherlock-holmes-the-strand-magazine-mensual-ilustrado-editado-por-g-newnes-londres-george-newnes-1891-1950-fuente-p-p-6004-glk-de-enero-de-1924-r5g2km.jpg)
El relato "La aventura del vampiro de Sussex" está descrito así:
- P179 (Serie) El archivo de Sherlock Holmes; Canon Holmesiano
- P1433 (Publicado en) El archivo de Sherlock Holmes
Combinando parte (P527) y serie (P179), en direcciones opuestas, podemos obtener unos resultados potables.
SELECT ?parte ?parteLabel ?elemento ?elementoLabel WHERE {
wd:Q2316684 wdt:P527+ ?parte .
?elemento wdt:P179 ?parte
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". } }
Esta consulta recupera solo los relatos que forman parte de libros que los recopilan, pero no los libros que son historias independientes. Sería necesario hacer una operación de UNION de consultas, de forma que los resultados se aproximen a la realidad (58 items).
SELECT ?elemento ?elementoLabel WHERE {
{
wd:Q2316684 wdt:P527+ ?parte .
?elemento wdt:P179 ?parte .
}
UNION {
wd:Q2316684 wdt:P527 ?parte .
MINUS { ?relato wdt:P179 ?parte }
BIND(?parte as ?elemento)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". }
}
Ahora, mi pregunta es ¿Cómo calcular un ranking para estas obras compuestas? Seguramente habría que integrar los resultados de todas ellas. Por ejemplo, para las 5 piezas que componen el señor de los anillos, obtenemos estos valores:
Ítem | Label | NWikis | NProps | NWords | Wiki3DRank |
---|---|---|---|---|---|
Q15228 | El Señor de los Anillos | 113 | 121 | 178564 | 13.847157821603203 |
Q208002 | La Comunidad del Anillo | 50 | 42 | 45435 | 12.025445624091725 |
Q332388 | Las dos torres | 43 | 28 | 35031 | 11.625593685119489 |
Q332581 | El retorno del Rey | 41 | 28 | 26441 | 11.357658940911755 |
Q332139 | Prólogo | 4 | 10 | 5904 | 9.151191991124808 |
Q334335 | Apéndices | 2 | 11 | 890 | 7.315576042962506 |
A bote pronto diría que la entidad agregada [El señor de los aniños, como libro único y como tres libros independientes] tendría estos valores. En el caso de las Wikipedias en las que aparece y las propiedades, se sumarían los valores diferentes, y en el caso del número de palabras se sumarían, y su score en Wiki3DRank incrementando unos 0,5 puntos en este caso.
item | Label | NWikis | NProps | NWords | Wiki3DRank |
---|---|---|---|---|---|
El Señor de los Anillos (Total) | 113 | 131 | 292265 | 14,3006449 |
Finalmente ¿Se puede operacionalizar este enfoque? ¿Se puede programar la detección automática de obras con partes significativas, y obtener sus valores para calcular una medida que represente a las obras agregadas?