Esbozamos una idea de investigación aplicada relativa a la disponibilidad de buenos datos sobre traducciones literarias. Partamos de lo que Katie King expresa en su nota "Why literary translation data matters"
But the fact is there is no agreed method for consistent, detailed tracking literature in translation to English. Even with the world’s most robust research institutions – UNESCO’s Index Translationum, the British Library and WorldCat, the global database of books — it is difficult if not impossible to get full, reliable data on translated works.
Katie King, "Why literary translation data matters", 2018
Recomendamos también la lectura del artículo Big Translation History. Data science applied to translated literature in the Spanish-speaking world, 1898-1945, de Diane Roig Sanz y Laura Fólica, publicado en 2021 en Translation Spaces. Aborda la dificultades de extraer datos sobre traducciones directamente de los catálogos de biblioteca, y las resuelve mediante su procesamiento previo con técnicas de data-scice.
Undoubtedly, extracting knowledge from library catalogues is difficult because of their unstructured and heterogeneous archives. This is the case when conducting large-scale work with various national libraries from, for example, Latin-America, as its libraries rely on disparate ways of indexing their material, digitization and preservation policies, and budgets. For this reason, and despite the great potential they hold for researchers in translation history, these resources remain underexploited.
Diane Roig Sanz y Laura Fólica, Big translation history, 2021
![](https://www.um.es/metadatosdeficcion/wp-content/uploads/2023/12/adf38b23250569.563218c2d5026-1024x758.png)
No abundaremos en la falta de calidad de los datos del Index Translatiorum de UNESCO, ni en la inexplicable pobreza de su publicación como datos en la web. Vamos a estudiar cómo están modelados estos datos en Wikidata.
En Wikidata hay 50.787 items en los que se identifica la propiedad P655 (traductor). Se trata sobre todo de ediciones de obras (95%), y varios puñados de videojuegos, poemas, canciones, cuentos, obras de teatro y otros tipos de obras creativas. Encontramos también que 3.200 de esos items están caracterizados como "Traducción" (con dos códigos diferentes).
SELECT distinct ?tipo ?tipoLabel (count (?item) as ?n_trads) WHERE {
?item wdt:P655 ?traductor .
?item wdt:P31 ?tipo .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". } }
group by ?tipo ?tipoLabel
» Lanzar consulta en Wikidata
Usemos como ejemplo la obra Mujercitas de la escritora Louisa May Alcott. Wikidata, como práctica habitual, aplica un modelo a la Bibframe, diferenciando entre Obra y Edición, que están relacionadas a través de la propiedad P655 (has edition). Las ediciones se corresponden con items clasificados (P31) como " version, edition or translation" (Q3331189). Explorando esta obra accedemos a los datos de traductor, idioma, fecha y título traducido:
SELECT ?edition ?idiomaLabel ?traduccion ?date ?traductorLabel WHERE {
VALUES ?obra {wd:Q523076} #Libro mujercitas
?obra wdt:P747 ?edition .# Has edition
?edition wdt:P655 ?traductor .
?edition wdt:P577 ?date.
?edition wdt:P1476 ?traduccion . # Titulo de la traduccion
?edition wdt:P407 ?idioma
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". } }
ORDER BY ?date ?idioma
» Lanzar consulta en Wikidata
idioma | traducción | date | traductor |
---|---|---|---|
French | Les Quatre Filles du docteur Marsch | 1 de enero de 1880 | Pierre-Jules Hetzel |
Swedish | Unga kvinnor | 1 de enero de 1919 | http://www.wikidata.org/.well-known/genid/9626dff45ff78e80ec75db983dd16fa2 |
Swedish | Unga kvinnor eller Margret, Hanna, Betty och Amy | 1 de enero de 1919 | http://www.wikidata.org/.well-known/genid/9626dff45ff78e80ec75db983dd16fa2 |
Polish | Małe kobietki | 1 de enero de 1930 | Zofia Grabowska |
Los resultados son muy incompletos debido a varias razones:
Se duplica la edición en sueco, debido a que está registrada con dos títulos alternativos. Aparecen casos en los que el traductor es anónimo o desconocido, y que aparecen en un formato extraño. De momento no nos preocupamos de estas dos circunstancias. En el momento de escribir esta nota solo aparecían 3 traducciones de Mujercitas, lo cual, sin ni siquiera consultar otra fuente, sabemos que está claramente equivocado.
Al recabar información de varias propiedades, quedan excluidos aquellos items en los que falte cualquiera de ellas (traductor, idioma, fecha, título traducido). Esto requeriría utilizar OPTIONAL. En este caso habrá que tener en cuenta que aparecerán también las sucesivas ediciones en inglés, por lo que tendremos que excluir las ediciones en el mismo idioma que la obra original, porque solo nos interesan las ediciones traducidas.
SELECT ?edition ?idiomaLabel ?traduccion ?date ?traductorLabel
WHERE {
VALUES ?obra {wd:Q523076} #Libro mujercitas
?obra wdt:P407 ?idioma_original .
?edition wdt:P629 ?obra .# Edition of
MINUS { ?edition wdt:P407 ?idioma_original . # Exclusión idioma inglés
}
OPTIONAL { ?edition wdt:P655 ?traductor .
}
OPTIONAL { ?edition wdt:P577 ?date. }
OPTIONAL {?edition wdt:P1476 ?traduccion . # Titulo de la traduccion
}
optional {?edition wdt:P407 ?idioma
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". }
}
Esta consulta la hemos hecho en la dirección inversa, desde la Edición a la Obra (En seguida lo comentamos). Los resultados siguen siendo escasos, con traducciones al francés, polaco y sueco, e incluso se cuela alguna edición en inglés que no tiene registrado el idioma. Sigamos con los problemas de la dirección de las relaciones.
Dado que Wikidata es un grafo dirigido, los datos a veces se registran partiendo desde la Obra (Obra » P655 » Edicion), o bien en desde la Edición (Edicion » P629 (edition or translation of) » Obra). Ambas propiedades están declaradas como propiedades inversas (P1696). Sin embargo en este caso aparecen los mismos resultados. Los datos de Wikidata son los siguientes:
Relaciones Obra-Edición | Relaciones Edición-Obra | UNION Distinct |
114.347 | 124.902 | 122.293 |
No parece haber grandes diferencias al recorrer el grafo en ambas direcciones. Testamos que al unir las dos consultas, los resultados siguen siendo los mismos, por lo que las relaciones estaban establecidas en ambas direcciones.
SELECT DISTINCT ?edition ?idiomaLabel ?traduccion ?date ?traductorLabel
WHERE {
VALUES ?obra {wd:Q523076} # Libro Mujercitas
?obra wdt:P407 ?idioma_original .
{
?obra wdt:P747 ?edition . # Has edition
OPTIONAL { ?edition wdt:P655 ?traductor . }
OPTIONAL { ?edition wdt:P577 ?date. }
OPTIONAL { ?edition wdt:P1476 ?traduccion . } # Titulo de la traduccion
OPTIONAL { ?edition wdt:P407 ?idioma }
}
UNION {
?edition wdt:P629 ?obra . # Edition of
OPTIONAL { ?edition wdt:P655 ?traductor . }
OPTIONAL { ?edition wdt:P577 ?date. }
OPTIONAL { ?edition wdt:P1476 ?traduccion . } # Titulo de la traduccion
OPTIONAL { ?edition wdt:P407 ?idioma }
}
MINUS { ?edition wdt:P407 ?idioma_original . # Exclusión idioma inglés
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". }
}
ORDER BY ?date ?idioma
Por supuesto, también podemos usar Wikidata para recopilar la producción de traductores. Pongamos como ejemplo al reconocido traductor de Shakespeare, Ángel Luis Pujante. Podemos realizar la consulta porque su item personal existe previamente. Sin embargo estimamos que solo unos poquísimos traductores tendrán registro individual en Wikidata.
SELECT ?traductor ?edition ?idiomaLabel ?traduccion ?date ?traductorLabel WHERE {
VALUES ?traductor {wd:Q6173268}
?obra wdt:P747 ?edition .# Has edition
?edition wdt:P655 ?traductor .
OPTIONAL { ?edition wdt:P577 ?date. }
OPTIONAL {?edition wdt:P1476 ?traduccion . # Titulo de la traduccion
}
optional {?edition wdt:P407 ?idioma
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,es". } }
ORDER BY ?date ?idioma
Esta prueba de concepto nos permite constatar que aunque la estructura de datos de Wikidata permite manejar la información de traducciones, pero hay un problema enorme de contenido. Con respecto al modelo de datos, podemos manejar la información básica, aunque habría algunas complicaciones para resolver, entre otros, los siguientes aspectos:
- Registrar ediciones de diferente fecha que usan la misma traducción. El modelo opta por fechar la edición y no la labor del traductor.
- Registrar aspectos editoriales interesantes como las tiradas o las ventas.
Con respecto al contenido, esta prueba, y otras hechas a vuelapluma sobre El principito, o El nombre de la rosa, indica que los datos introducidos sobre ediciones en diferentes idiomas parecen ser muy muy incompletos. En el ISBN español hay 177 ediciones de Mujercitas, y en Wikidata no figura ninguna.
Tenemos estructura de datos y de consulta ¿Qué pasaría si UNESCO hubiera cargado sus datos en Wikidata? Tendríamos una información de mucha mejor calidad y, no se nos olvide, sostenible al estar en una plataforma abierta al enriquecimiento colectivo. Y esta sostenibilidad procede de dos fuentes, la licencia de datos libres y la plataforma abierta.
Nota final: Es muy posible que los datos cambien, no sólo porque Wikidata es una comunidad global 24x365, sino también porque a continuación de esta nota nos pusimos a hacer un experimento de localización de datos de traductores en el ISBN, extracción de datos relevantes con ChatGPT 3.5 y Copilot, y preparación de los datos para su carga en Wikidata a través del servicio Quickstatements. Ya lo contaremos en otro artículo.